ぴ

列の中のこのまとまりごとに何かしたい！って時に重宝するんだ

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.144.679.0 64-bit (2025年6月)」

グループ化された中で下方向にフィル

列1に入っている「あ」に対応する列2のデータは「a」ですが「空白」もあります。
「あ」が入っている行の列2にはすべて「a」、「い」が入っている行の列2にはすべて「b」、「う」が入っている行の列2には空白しかないので空のまま、「え」が入っている行の列2にはすべて「c」が入るようにしたいです。

例えば、列1で重複の削除をすると列2でnullのほうが残ってしまう…というときなんかに便利でした。

＜完成図＞

ぴ

グループ化と下方向にフィルを使うよ

列1と列2を両方選択して重複の削除をしたいとき、並び替えをしてからでもなんかうまくいかない時があるんですよね。Table.Bufferを使えばいいんですが、なんかそれを使うとめちゃくちゃ読み込みが重くなって詰むことがままあったのでこっちの方法で解決チャレンジしてみたいと思います。

も

まずは空白をnullにしよう

下方向にフィルは空白だとできません。そのため「空白」を置換で「null」に置き換えましょう。

そのあとは列1（昇順）→列2（降順）の順番で並び替えをします。

この状態で下方向にフィルを使っちゃうと、「い」と対応している「b」のデータが「う」のところまでコピーされちゃいます。でも「う」に対応する列2はnullなので「い」のデータは入ってこないでほしいです。

ということでホームタブにある「グループ化」を押してください。

グループ化の設定画面が出てきます。新しい列名は好きな名前を入れてください。
操作は「すべての行」を選択して「OK」を押します。これで列1を基準にグループ化（なんかまとめてくれる）されます。

ぷ

なんかまとまった

そしたら列の追加タブから「カスタム列」を追加します。
「＝」の後に Table と打って、出てくる選択肢の下のほうにある「Table.FillDown」を選んでください。

使用できる列には出てこないので手入力が必要ですが、グループ化された列の中にある「列2」で下方向にフィルしてねという式を描きます。

Table.FillDown([グループ化された列],{"列2"})

ぷ

なんか増えた

最初にグループ化で作った「グループ化された列」はもう使わないので削除しちゃってください。

新しくできた列「フィル（下）」の右横の矢印マークを押して、データを展開します。
列1はもともとあるので列2だけ選択しときます。

も

できた～！

グループ化された中でインデックスを付ける

同じ日付の中で1からインデックスを付け、日付が変わったらまた1からインデックスが付くようにしたいと思います。例えば、2025/6/20に対応する列2の行は3つあるので新しい列では1、2、3…となり2025/6/21の行からはまた1、2、3…って番号が振られる感じです。

＜完成図＞

下方向にフィルでやったようにグループ化していきます。
ホームタブから「グループ化」をクリックし、「すべての行」を選びます。

「OK」を押すと列1を基準にグループ化されますので、この状態で「カスタム列の追加」をします。

「＝」の後に Table と打って、出てくる選択肢の「Table.AddIndexColumn」を選んでください。
「グループ化された列」に対して「インデックス」という名前の列を追加し、1から番号を振ってもらいます。

ぴ

手入力の列名は「””」で囲うのを忘れないように

Table.AddIndexColumn([グループ化された列],"インデックス",1)

M言語の中の赤文字「”インデックス”」はただの新しく作る列名です。適当に入力してください。

最初に作った「グループ化された列」はもういらないので削除し、今作った「インデックス」列の右横にある矢印マークを押してデータを展開します。

ぷ

ちゃんと日付ごとに順番が振りなおされてる

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.143.1378.0 64-bit (2025年5月)」

データの中に「原価」「単価」「売上」の列があったので、とりあえずそれらを使ってやってみます。普通にグラフを作ると下の画像みたいになりますよね。これをひとまとめにします。

ぷ

ま、横並べて比較しないといけないんじゃないなら一つのグラフにしたほうがすっきり見えていいよね

ぴ

必要な情報のみに絞って表示させるって大事だからね

パラメーターを使ってグラフの表示を切り替える

みなさんパラメーターって使ったことありますか？今回はこれを使っていきます。

まずは切り替え表示をするための下準備をします。「モデリング」タブの「新しいパラメーター」を見つけてください。ここでは「フィールド」を使います。

この後切り替え表示に使いたいデータを指定します。ここで一つ注意なのですが必ず集計済のメジャーを用意してください。Σが付いている列はパラメーターに指定はできますが表示されないという現象が発生します。（私は普通にこれやって混乱してました）

左の表に入っているΣのデータはすべて使えません。SUMとかでメジャーを作ってください。

メジャーは以下を用意します。

メジャー：原価 = SUM('2025_売上'[原価])

メジャー：単価 = SUM('2025_売上'[単価])

メジャー：売上 = SUM('2025_売上'[売上])

では改めて、「モデリング」タブの「新しいパラメーター」をクリックして「フィールド」を選択します。
するとパラメーターの設定画面がポップアップで出てくるので、切り替えに使いたいメジャーを選択して作成してください。

「変数は何を調整しますか？」にはフィールド、「名前」には自分が分かりやすいパラメーター名を入力します。「フィールドの追加と並び替え」には右側から追加したいメジャーのチェックボックスをクリックすれば入ります。ドラッグアンドドロップで順番の並び替えもできますよ。
設定し終わったら「作成」を押してください。

作成を押すとなんか勝手にスライサーと関数が作られます。

このスライサーを使ってポチポチすればグラフが切り替えられます。ボタン名を変えたければ、上に表示されているDAX関数の赤文字のところを変えてください。

も

あともう一息！

最後にグラフを作ります。データのところにパラメーターで作成されたデータが作られています。これをグラフのX軸なりY軸なりに入れてください。

入れたときは全部表示されますが、スライサーをポチポチすれば、選択したデータだけで見ることができます。スライサーを単一選択だけにする設定にしておくといいかもしれませんね。

ぷ

グラフタイトルも！タイトルもスライサーに合わせて変わってほしい！

ぴ

できるよ

グラフタイトルもやっちゃいましょう。作ったグラフを選択して「ビジュアルの書式設定」を開いてください。
今はタイトルの中にテキスト文字が入っています。この横にある「fx」ってかいてあるボタンを押してください。

ポップアップが出てくるので、「基準にするフィールド」でさっき作ったパラメーターを選択してOKを押せば完了です。

も

使ってみよう！

原価のみ▼

単価のみ▼

売上のみ▼

ぷ

スライサーに合わせてグラフタイトルも表示データも変わってる

も

やったー完成だ～！

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.143.1204.0 64-bit (2025年5月)」

そもそもカレンダーテーブルとは何か？なんですがすごくざっくり言うと、連続した日付データが入っているデータ一覧です。これがあると、日付スライサーが使いやすくなったりDAX関数に使えたり色んな日付単位でグラフに表示できたりします。

ここからはすでにPower BIに何かしらのデータを取り込んでいて、さらにそのデータに日付列がある前提で話していきます。

ぴ

カレンダーテーブルを作らなくてもグラフ自体は作れるけど、Power BIを使っていくなら絶対作っておいたほうがいいよ

カレンダーテーブル = ADDCOLUMNS( CALENDARAUTO (),
        "年", YEAR([Date])&"年",
        "月", MONTH([Date])&"月",
        "日", DAY([Date])&"日",
        "曜日", FORMAT([Date],"aaa"),
        "年&月", FORMAT([Date],"yyyy年MM月"),
        "月&日", FORMAT([Date],"MM月dd日"),
        "日（曜日）", FORMAT( [Date],"dd(aaa)"),
        "年度", FORMAT(YEAR([Date]) - IF(MONTH([Date])<4,1,0),"0年度"),
        "四半期", SWITCH(TRUE(),MONTH([Date])<4,"第4四半期",MONTH([Date])<7,"第1四半期",MONTH([Date])<10,"第2四半期","第3四半期"),
        "上期下期", SWITCH(TRUE(),MONTH([Date])<4,"下期",MONTH([Date])<10,"上期","下期"),

        "並替_月", MONTH([Date]),
        "並替_曜日", WEEKDAY([Date], 1)
)

日付の取得範囲を決める

カレンダーテーブルを作るときに連続した日付データをどこからどこまで作るかを決めることができます。私は普段CALENDARAUTOばかり使っていたので、もいっかい調べなおしてみました。

CALENDAR関数で取得する日付範囲を指定する

CALENDAR関数を使えば、ここからここまでの連続した日付データを作ってくださいね～と細かく指定することができます。日付データが存在していない未来の日付も作りたいときはこれがいいかもしれません。

例えば、2025/4/1～2025/9/31までの範囲の連続した日付データを作りたいときは以下のように書きます。
Power BIの「新しいテーブル」をクリックして以下のDAX関数を入れてみてください。

カレンダー（CALENDAR） = CALENDAR(DATE(2025,4,1),DATE(2025,9,31))

日付を指定できますが、範囲が変わるときは手動で直さないといけないのでそこだけ注意ですね。

CALENDARAUTO関数で自動的に日付範囲を取得する

手入力でいちいち指定するのがめんどい場合はCALENDARAUTO関数がおすすめです。CALENDARAUTO関数はPower BIで読み込んでいるデータ内のすべての日付列を参照し、最も古い日付と最も新しい日付の間の連続した日付データを作成します。

DAX関数の書き方は以下です。超シンプルですね。

カレンダー（CALENDARAUTO） = CALENDARAUTO()

ちなみに、私が今操作しているPower BIには別テーブルに「売上日」という日付データが入っていて、売上日列に入っている一番古い日付が2025/1/1なので、その日から連続した日付データが作られています。

CALENDARAUTO関数はすべての日付列を参照するので、もし売上日以外に発送日とか入力日とかいう列があればそれらもすべてひっくるめて一番古い日付と一番新しい日付を引っ張ってきます。

も

なんかたまに1800年代とかすごく古い日付が出てくるときあるんだよね

ぷ

日付列なんて複数あることも多いし、どこからその日付が出てきたのか混乱するときはある

CALENDAR関数で指定した列の日付範囲を動的に取得する

カレンダーテーブルを作ったら元々読み込んである日付列とリレーションを組むことになるのですが、基本的に一つのカレンダーテーブルに一つの日付列をリレーションします。つまり、一つのカレンダーテーブルを売上日と発送日に結び付けて使うことはしません。それに、データとしては入っているけど正直あまり使わない日付列があるときもあります。

CALENDARAUTO関数を使うと、たまにどっから出現したんだ？っていうような日付から作成されることがあります。そういう時にはこの方法を使うとよさそうです。

ということでCALENDAR関数を使って、どの日付列の日付範囲を取得するのか指定したいと思います。

カレンダー（CALENDAR_動的） = CALENDAR(
    MIN('2025_売上'[売上日]),
    MAX('2025_売上'[売上日])
)

ぴ

「売上日」列の最も古い日付と最も新しい日付を取っているカレンダーだって分かりやすいね

個人的にはこれが一番使いやすそうで好きです。これからはこの書き方にしようかな…

可視化で使いやすいように表示形式を指定しよう

カレンダーテーブルを作る関数が分かったのはいいんですが、上で紹介した関数で作った日付列って年月日がくっついた2025/01/01の表示形式しかないんですよね。もう少し正確に言うと、グラフに入れたら下の画像みたいに「年」「四半期」「月」「日」で分解できるんですが、年は2025のみですし、四半期は4月始まりじゃなくて1月が1Qですし、月なんて英語ですし（英語できないので）正直使いづらいです。

ぴ

ちなみに、yyyy/MM/ddで表示したいときはDateの右横の▽を押して「日付の階層」ではなく「Date」を選んでみて

さて、グラフで表示するときは色々な区切りで見えたほうがいいですよね。ということでここからは以下の単位でグラフに表示できるようにしたいと思います。

・年（例：2025年）
・月（例：1月）
・日（例：1日）
・曜日（例：火）
・年&月（例：2025年1月）
・月&日（例：1月1日）
・日（曜日）（例：1日（月））
・年度（例：2025年度）
・四半期（例：1期）
・上期下期（例：上期）

カレンダーを作るための関数の下に、どんな表示をしたいのか関数を入れていきます。今回はとりあえずCALENDARAUTO関数を使っていきますが、ここからは列をどんどん追加していきたいのでADDCOLUMNSも使用します。

列の追加方法ですが、CALENDARAUTO関数を使うと自動的にできる「Date」列から使いたい部分だけ抜き出して、使いたい表示形式にするイメージです。

も

とりあえずやってみよ～

「20XX年」と表示できる列を作る

追加するDAX関数の意味としては「Date列の年に当たる部分を抜き出して20XX年と表示する」という感じです。

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "年", YEAR([Date]) & "年"
)

最初の赤文字の”年”は列の名前になります。YEAR（）はDate列から年の部分だけ抽出してくれます。「&”年”」を加えることで抽出した年の数字の後ろに「年」という文字をくっつけることができます。これで「2025」だけではなく「2025年」と表示させることができるようになりました。

ぷ

この感じでどんどん作ろ

「X月」と表示できる列を作る

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "月", MONTH([Date]) & "月"
)

ぴ

上で作った年に加えて追加したい場合は年の後ろに「,」を入れてから追加するんだよ

も

このままグラフに使うと月の順番がごちゃごちゃになっちゃう

ぴ

それはこの後の並び替えで解決しよう

「X日」と表示できる列を作る

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "日", DAY([Date]) & "日"
)

曜日を表示できる列を作る

今度はFORMAT関数を使っていきます。Date列は日付列として入っているんですが、FORMAT関数を使うとこれを文字列として指定した形式に変換してくれます。aaaは曜日を表します。

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "曜日", FORMAT([Date],"aaa")
)

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "曜日", FORMAT([Date],"aaa曜日")
)

年＆月 / 月&日 / 日（曜日）を表示できる列を作る

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "年&月", FORMAT([Date],"yyyy年MM月")
)

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "月&日", FORMAT([Date],"MM月dd日")
)

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "日（曜日）", FORMAT( [Date],"dd(aaa)")
)

画像だとDDって書いちゃってるんですがddのほうがいいみたいです。

年度を表示できる列を作る

2025年の場合、2025年1月～3月は「2024年度」、2025年4月～2026年3月までは「2025年度」と表示できるようにしたいです。

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "年度", FORMAT(YEAR([Date]) - IF(MONTH([Date])<4,1,0),"0年度")
)

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "年度", "FY" & RIGHT(FORMAT(YEAR([Date]) - IF(MONTH([Date])<4,1,0),"0000"),2)
)

先にIFのところから解説します。IF()に書いてある内容は「もし月が4月未満（＝1月～3月）だったら１、それ以外（＝4月～12月）なら０を返す」という意味です。FORMATの後ろにある式は「（年）ー（IFの結果）」なので、もし月が4月未満だったら「2025 – 1 = 2024」、4月以降なら「2025 – 0 = 2025」が返ってきます。それに「年度」をくっつけるので、2024年度もしくは2025年度の文字列が列に入ってくるというわけです。

二つ目の式はRIGHT関数で、2025の右側2文字だけ抜き出して頭にFYって付けて～ってやっています。

も

年度表示できるの助かる～

四半期を表示できる列を作る

四半期はSWITCH関数を使ったやり方にしました。

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "四半期", SWITCH(TRUE(),
        MONTH([Date])<4,"第4四半期",
        MONTH([Date])<7,"第1四半期",
        MONTH([Date])<10,"第2四半期",
        "第3四半期")
)

上から優先的に適用されます。<4（1月～3月）は第4四半期、<7（3月まではすでに第4四半期と指定してあるので残りの4月～6月）は第1四半期、<10（6月まではすでに第1四半期と指定してあるので残りの7月～9月）は第2四半期、最後に残った10月～12月は第3四半期っていう感じです。

上期下期を表示できる列を作る

四半期と同じ感じで作ってみます。

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "上期下期", SWITCH(TRUE(),MONTH([Date])<4,"下期",MONTH([Date])<10,"上期","下期")
)

表示形式の並び替えを指定する

実は上で作った月の列をそのままグラフに使うと、月の順番がおかしくなってしまうんですよね。

ぴ

文字列として認識されているから頭に1が付いている10月11月12月1月が先頭に並び替えされるんだよね

ぷ

どうしたらいいの？

ぴ

順番を指定できる列を用意する必要があるね

というわけで、1月～12月の順番で並ぶように、1月は「1」という並び替え用の列を作っていきたいと思います。

並び替え用の列を作ったら、並び替えの指示をPower BIにしなければなりませんが、その方法は一番下に記載するのでそっちも忘れずにご覧ください。

「月」の並び替えを指定するための列を作る

分かりやすいように、月の列と一緒に並び替え用の列を作成しています。並び替え用の列は整数列になっています。
これで1月は1番目という対応した列ができます。

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "月", MONTH([Date])&"月",
    "並替_月",MONTH([Date])
)

「曜日」の並び替えを指定するための列を作る

曜日も同じように並び順がおかしなことになっていると思うので、指定できる列を作っていきます。

日曜日から並べたい場合 ▼

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "曜日", FORMAT([Date],"aaa"),
    "並替_曜日", WEEKDAY([Date], 1)
)

月曜日から並べたい場合 ▼

カレンダーテーブル = ADDCOLUMNS(CALENDARAUTO(),
    "曜日", FORMAT([Date],"aaa"),
    "並替_曜日", WEEKDAY([Date], 2)
)

も

WEEKDAYの後ろに1か2を入れることで並び始めの曜日を指定できるんだね！

並び替え列を使って表示並び替えを指定する

上で並び替え用の列を作りましたが、列を作っただけだと並び替えできません。そこでテーブルビューに行ってこの列の順番で並び変えてねと教えてあげる必要があります。

今回は「月」と「曜日」の並び替え用の列を作ったのでそれの指定をしていきます。

まずは「月」列を選択してください。列を選択すると「列ツール」タブが出現します。その中に「列で並び替え」という項目があるのでクリックして「並替_月」を選択してください。

ぴ

これで「月」の文字列を「並替_月」列で並び替えるっている指定ができたね

も

曜日も同じように指定してあげればいいんだね

並び替え指定前 ▼

並び替え指定後 ▼

リレーションも忘れずに！

Power Queryでのカレンダー作成はこちら

前月値の出し方についてはこちらの記事で↓

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.142.1277.0 64-bit (2025年4月)」

今月の売上と前月の売上を使って集計する

今回も売上が入っているテーブルと、売上日とリレーションを組んでいるカレンダーテーブルを使っていきたいと思います。2025_売上テーブルの「売上」列、カレンダーテーブルの「Date」列を使用します。

前月差

前月差はシンプルに今月と前月の間にどれぐらいの増減があるのかを見ることができます。
「今月の売上ー前月の売上」で出すことができます。

前月の値を表示するメジャーを先に作っておいて、それを使って計算をする方法もわかりやすくていいですが、せっかくなのでひとまとめにします。

前月の値には「LastMonth」、今月の値には「ThisMonth」という変数名を付けることにしました。

前月差 = 
    VAR LastMonth = CALCULATE(SUM('2025_売上'[売上]),DATEADD('カレンダー'[Date],-1,MONTH))
    VAR ThisMonth = SUM('2025_売上'[売上])

RETURN
    IF(ISBLANK(LastMonth),BLANK() ,ThisMonth - LastMonth)

普通に作ると前月の値が入っていない場合（0ではなくそもそもデータがない）はそのまま当月の値が返されますが、前月の値がないなら前月差を返してこなくてもいいかと思ったので、RETURNの後に「もし前月値が空白なら前月差は空白を返して、そうじゃないなら 今月値ー前月値 を返して」という式を入れています。その指定が不要なら「ThisMonth – LastMonth」だけ記載しておけばOKです。

ぴ

0とnullは違うんだ。気を付けないとね

前月比

前月比は、前月の値に対する今月の値の割合を計算することで、今月の値の増減を相対的に見ることができます。
比率とか聞いただけで逃げたくなりますがやっていきましょう。増えたか減ったかわかればよくないですか？

も

逃げないで。頑張って

ぴ

単純な数値で見るより増減のインパクトが分かりやすいし、意外と見落としがちなことに気が付くことができるよ。例えば、前月より+10の月と+100の月の前月比を見てみたら実はどちらも10%だった…とかね

使いこなせるようになりたいですね。前月比は　今月の値 ÷ 前月の値 × 100　で出すことができます。×100のところはPower BIの表示指定で数値から％に変更できるので、その前までの部分を出していきます。

前月比 = 
    VAR LastMonth = CALCULATE(SUM('2025_売上'[売上]),DATEADD('カレンダー'[Date],-1,MONTH))
    VAR ThisMonth = SUM('2025_売上'[売上])

RETURN
    DIVIDE(ThisMonth,LastMonth)

作成した前月比メジャーは右側のデータタブに表示されています。作成したメジャー名をクリックして選択すると、上に「メジャーツール」タブがぽんっと出現するので、そこで％表示にしてください。勝手に×100されます。

ということで前月比も出ました。

伸び率・成長率・増加率

伸び率は前月の値からの増減部分に注目して、どれだけ増減したかをパーセントで見ることができます。前月比は「前月と比較した今月の値の比率」であり、単純に今月の値が前月の何倍になっているかが分かりますが、伸び率は「前月と比較してどれだけ増減したか」という変化の幅を把握しやすいみたいですね。

伸び率は今回のように売上などの特定のデータを計算するときに使われることが多いみたいなので、今回は「伸び率」と表現しますが、成長率も増加率も基本的な計算方法は同じようです。ただ、成長率は通常、年単位で計算し企業や経済の成長を示すのに使われ、増加率は人口などを表すときによく使われるという文脈の違いがあるようです。とりあえず「文脈の違いがある」ということだけ抑えておこうと思います。

も

人に説明するときには使い方に気を付けないとだね

ぴ

年単位で見たければDATEADDの後ろのMONTHをYEARにすればいいよ

伸び率は　（今月の値ー前月の値）÷ 前月の値 × 100　です。

伸び率 = 
    VAR LastMonth = CALCULATE(SUM('2025_売上'[売上]),DATEADD('カレンダー'[Date],-1,MONTH))
    VAR ThisMonth = SUM('2025_売上'[売上])

RETURN
    DIVIDE(ThisMonth - LastMonth,LastMonth)

ぷ

分かりやすい

も

書式設定でプラスだけ色を変えるのもよさそう！

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「バージョン: 2.142.928.0 64-bit (2025年4月)」

完成イメージはこんな感じ。

ぴ

2月の行には２月の売り上げと先月（１月）の売り上げが表示されているよ

も

これができたらあとは引き算するだけで前月差がわかるね！

前月の値を表示する

今回は売上が入っているテーブルと、売上日とリレーションを組んでいるカレンダーテーブルを用意しました。
2025_売上テーブルの「売上」列、カレンダーテーブルの「Date」列を使って前月の値を出していきます。

ぴ

結論から言うとDATEADD関数が使いやすいと思う

PREVIOUSMONTH関数

PREVIOUSMONTH関数というものを使ってみようと思います。関数名を見るとMONTHと入っていますが、実はこのほかに「PREVIOUSDAY（日）」「PREVIOUSQUARTER（四半期）」「PREVIOUSYEAR（年）」もあります。PREVIOUSはそのまま「前の」という意味です。見たい単位にあった関数を選んでくださいね。

カレンダーテーブルのDateを基準に前の月を出してください～という感じで関数自体が前月を表すのでわかりやすいなと思います。

売上合計の前月分を出す式は以下です。
カレンダー[Date]は売上日列とリレーションを組んでいるので、つまり売上日を基準に前月の売上合計が出ています。

前月値_PREVIOUSMONTH = CALCULATE(SUM('2025_売上'[売上]),PREVIOUSMONTH('カレンダー'[Date]))

ぷ

ちゃんと出てる～

DATEADD関数

今度はDATEADD関数を使います。さっきのPREVIOUSMONTH関数と違うのは何か月前のデータを持ってくるか指定ができるので汎用性が高いことです。

前月値_DATEADD = CALCULATE(SUM('2025_売上'[売上]),DATEADD('カレンダー'[Date],-1,MONTH))

DATEADD(‘カレンダー'[Date],-1,MONTH)の「-1」と「MONTH」のところは適宜変えることができます。

DATEADD(‘カレンダー'[Date],-3,MONTH)とすれば3か月前ですし、DATEADD(‘カレンダー'[Date],-1,DAY)にすれば１日前になります。「-（マイナス）」を付けなければ未来の値を持ってくることもできるので、3か月後や１年後と比較することもできます。

DATEADD関数も「MONTH（月）」の他に「DAY（日）」「QUARTER（四半期）」「YEAR（年）」を選べます。

PARALLELPERIOD関数

最後はPARALLELPERIOD関数です。式の見た目はDATEADD関数と同じです。ただ、DATEADD関数と違ってPARALLELPERIOD関数はどうやら「DAY」は選べないみたいですね。指定できる期間は「月」「四半期」「年」のみです。

前月値_PARALLELPERIOD = CALCULATE(SUM('2025_売上'[売上]),PARALLELPERIOD('カレンダー'[Date],-1,MONTH))

PREVIOUSMONTH関数やDATEADD関数との違いがあんまりピンとこなかったのですが、PREVIOUSMONTH関数は”前”月のみ出すことができるのに対し、PARALLELPERIOD関数は前月も来月も取ることができる。PREVIOUSMONTH関数よりは柔軟性がありDATEADD関数よりかは柔軟性がないみたいな理解でいいのかなと思っています。

柔軟性の高さ
DATEADD関数＞＞PARALLELPERIOD関数＞PREVIOUSMONTH関数

も

とりあえずDATEADD関数を使っておけばいいかな

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.140.1577.0 64-bit (2025年2月)」

データラベルを表示する

データラベルは「ビジュアルの書式設定」から「データラベル」をONにすれば表示できます。凡例を入れた場合２パターン表示方法があります。

凡例のデータラベルを表示する

凡例を入れた状態でデータラベルをONにするとこんな感じで凡例ごとに表示されます。

合計も見たい場合は、データラベルの下にある「合計ラベル」をONにしてみてください。
凡例のデータラベルと見分けがつきやすいように合計ラベル内の「背景」をONにしました。

も

Power BIで作ったカレンダーテーブルをPower Queryに読み込めないかなって思ったけどできなかった

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.141.1558.0 64-bit (2025年3月)」

とりあえずPower Queryを開いて適当に日付を記入したクエリを作成しました。一番古い2025/1/27から一番新しい2025/6/20までのすべての日付一覧が作成されるのを目指します。

ぷ

Power Queryの「クエリ」とPower BIの「テーブル」と「データ」の違いがよくわかんない

も

わかりみ

Power QueryだとCALENDARAUTOみたいなのは無いみたいなので最小値と最大値を取ってカレンダーを作っていきます。EdgeにくっついているCopilotに聞きまくったので早速やりましょう。Copilotは詳細エディターにコピペできるコードを教えてくれましたがあんまり理解できていないので一つずつ作ります。

まずはPower Queryのホームタブにある「詳細エディター」をクリックして一番上のコードを確認しておいてください。

letの下に「ソース」と書いてあります。もしここが英語でソースになっていた場合はこの後の「ソース」は「Source」に変えてもらえればうまく動くんじゃないかと思います。

それではカスタム列を作って日付の最大値を取っていきます。
列の追加タブからカスタム列を選択して以下のコードを入力します。[日時]のところは最大値を取りたい列の名前を右から挿入してください。

= List.Max(ソース[日時])

同じように最小値も作っておきます。

= List.Min(ソース[日時])

作ったカスタム列は忘れずに日付型に変えておきましょう。

ぴ

いい感じ

この最大値・最小値を使ってカレンダー列を作ります。カスタム列を作成して以下のコードを入れてください。

= List.Dates([最小値],Duration.Days([最大値] - [最小値]) + 1,#duration(1,0,0,0))

List.Dates([最小値] のところはリストの開始日を指定しています。今回で言うと2025/01/27からカレンダーを作ってねということですね。
Duration.Days([最大値] – [最小値]) + 1 はこの間の日数ですよっていうことでしょう。 + 1 にすると最大値も最小値も含めて返すことができます。
#duration(1,0,0,0)) はduration(days, hours, minutes, seconds)の構成になっていて、今回daysのところに1が立っているので「1日ごとに」ということです。

作ったカスタム列は閉じた状態になっているので列名の横の矢印ボタンをクリックして「新しい行に展開する」を押します。

完成です～！
残したい列を選択→右クリック→他の列の削除で不要な列は消しといてください。

DAX関数のカレンダーテーブルはこちら

ぴ

早速やってみよう

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.140.1577.0 64-bit (2025年2月)」

ラベルをすべて表示する

も

これって何とかなるんだ

横棒グラフのラベル見切れはグラフの幅を長くすれば解決します。しかし、１ページに複数グラフを配置する場合ラベルが見切れない長さまで横棒グラフの幅を長くするのは難しいことが多いです。以下の手順で解決しましょう。

横棒グラフ　見切れ解決手順

① 視覚化から「ビジュアルの書式設定」を開く
② Y軸の中の「値」を展開する
③ 「最大幅（%）」をラベルが見切れなくなるまで大きくする

ぷ

これでも見切れるぐらい長い場合はどうしたらいいの

ぴ

読む側も大変だから短くしてあげて

縦棒グラフ　ななめ解決手順

① 視覚化から「ビジュアルの書式設定」を開く
② X軸の中の「レイアウト」を展開する
③ 「カテゴリの最小幅（px）」を調整する

スクロール状態が解除されるとなぜかななめに戻るときがあります。。。

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.139.2054.0 64-bit (2025年1月)」

ぴ

この表を使おう

カテゴリごとの合計/カテゴリごとの割合を出す

ALL関数

カテゴリ（野菜・果物）ごとの商品名（いちご・キャベツetc.）の数量の割合を表示させるために、まずはカテゴリごとの数量の合計を出したいと思います。
カテゴリが野菜の商品名の横に、野菜のすべての数量合計値が表示されるという感じです。
これができれば、野菜・果物それぞれを分けた商品名の割合を出すことができます。

今回使っているデータの果物の数量の合計は1,599個、野菜の数量の合計は3,141個です。
メジャーを作ってこれらの数値が表示されればOKです。

も

野菜・果物ごとの合計を出して割ればいいんじゃないかな

まずは試しにCALCULATE関数でカテゴリを野菜だけに絞って合計を出してみましょう。

CALCULATE_野菜合計 = CALCULATE(SUM('2025_売上'[数量]),'2025_売上'[カテゴリ]="野菜")

も

野菜の数量の合計はちゃんと出ているみたい

ではこれを商品名も書いてある表に入れてみます。

も

えっなんか思ってたのと違う！野菜合計の列には全部3,141って入ってほしいのに商品名ごとの合計になってる

ぴ

表に入っているデータに合わせてフィルターがかかったみたいだね

フィルターがかからないようにするにはALL関数を使えばいいみたいなのでやってみたいと思います。

Power BI曰くALL関数とは「テーブルのすべての行、または列のすべての値を返します。適用されている可能性があるフィルターはすべて無視されます。」とのこと。

ALL関数 = CALCULATE(SUM('2025_売上'[数量]),ALL('2025_売上'[商品名]))

ぴ

商品名に左右されずに、果物は果物の合計数量である1,599、野菜は野菜の合計数量である3,141がちゃんと表示されているね

ぴ

「商品名」のフィルターをALL関数でクリアしているから、その次に入っているカテゴリごとでフィルターがかかって果物ごと野菜ごとで数量の合計が表示されているんだ

このメジャーを使って果物ごと野菜ごとの割合を出してみましょう。

カテゴリ割合 = DIVIDE(SUM('2025_売上'[数量]),'2025_売上'[ALL関数])

も

わーい

注意点として、ページ右横にある「フィルター」で商品名を絞っていたとしてもALL関数でフィルタークリアされます。
最初、なんとなくこの「フィルター」で商品名を絞ったら、表に入れたALL関数のメジャーも絞った後の合計がでるのかなと思っていたので危なかったです。それについてはこの後のALLSELECTED関数を見てください。

ぷ

…？ カテゴリ割合の合計おかしくない？

ぴ

ALLSELECTED関数なら大丈夫だったと思う
スクロールしてそっち見て

全体の合計/全体の割合を出す

ALL関数

上の表の商品名の数量が全体の合計数量である4,740のうち何％を占めているのかを出して表示したいと思います。

ぷ

さっきの感じだと、SUMで全体の合計を出して割るんじゃあダメなんでしょ

もう一回やってみましょう。SUMの合計メジャーとそれで割って割合を出したメジャーを入れます。

数量合計 = SUM('2025_売上'[数量])

数量割合 = DIVIDE(SUM('2025_売上'[数量]),'2025_売上'[数量合計])

ぷ

うわーやだー

ぴ

SUMで全体の合計を出したつもりでも、表に入れれば商品名で分解されちゃうね

ぴ

さっきのALL関数で今度は「商品名」も「カテゴリ」もフィルタークリアしよう

先ほどは商品名のみALL関数を使って記述しましたが、今回はその後ろにカテゴリも追加されています。

ALL関数_数量合計 = CALCULATE(SUM('2025_売上'[数量]),ALL('2025_売上'[商品名]),ALL('2025_売上'[カテゴリ]))

割合を出すメジャーも作ります。

数量割合 = DIVIDE(SUM('2025_売上'[数量]),'2025_売上'[ALL関数_数量合計])

では表に入れてみましょう。

ぷ

いいね

ぷ

でもこれ表の中の全部の列を指定しないといけないの？めんどみMAX

ぴ

列じゃなくテーブル全部も指定できるんだ。結果は一緒だよ

ALL関数その２ = CALCULATE(SUM('2025_売上'[数量]),ALL('2025_売上'))

実は後から気が付きました。列ごとに指定するより上のやつ使ってください。

完成
並べるとこんな感じです。
メジャー名が適当なのは目をつぶってください。なにも考えてませんでした…。

ALLEXCEPT関数

全体の合計を固定で出したいならALL関数よりもっといいのがあるのを見つけました。
ということでALLEXCEPT関数を使ってみようと思います。

Power BI曰くALLEXCEPT関数とは「指定された列のフィルターの影響を受ける行を除く、テーブル内のすべての行を返します。」とのこと。

ぴ

ALLEXCEPTを使うと一つずつ列をALL関数でフィルタークリアしなくてよくなるよ

ALL関数▼

ALL関数 = CALCULATE(SUM('2025_売上'[数量]),ALL('2025_売上'[商品名]),ALL('2025_売上'[カテゴリ]))

ALLEXCEPT関数▼

ALLEXCEPT関数 = CALCULATE(SUM('2025_売上'[数量]),ALLEXCEPT('2025_売上','2025_売上'[数量]))

結果比較▼

も

ちゃんと数字がでてる！

ALLEXCEPT関数は指定した列以外のフィルターをクリアすることができます。先ほどのALL関数ではフィルターをかける側を指定してフィルターのクリアをしていました。

ALLEXCEPT関数ならフィルターをかけられる側、つまりフィルターの影響を受けたくない「数量」を指定すればいいのでわかりやすいですね。

全体の合計/全体の割合を出す（でもスライサーは使いたい）

ALLSELECTED関数

ぷ

ALL関数やALLEXCECT関数だとスライサーや視覚化の隣のフィルターが使えないのがなぁ

も

スライサーで絞った値に合わせて合計も変化してほしいね

上の表ではオレンジ、キャベツ、きゅうり、じゃがいもの４つでスライサーをかけています。であるならば表内の合計も選択した４つの合計1,206が表示されて欲しいですね。スライサーで選択した項目によって分母である合計値が変わるイメージです。

ぴ

ALLSELECTED関数を使おう

Power BI曰くALLSELECTED関数とは「テーブルのすべての行、または列のすべての値を返します。クエリ内で適用されている可能性があるフィルターはすべて無視されますが、外部からのフィルターは保持されます。」とのこと。

ALLSELECTED関数 = CALCULATE(SUM('2025_売上'[数量]),ALLSELECTED('2025_売上'))

ちゃんとスライサーで選択した商品の数量合計になっていますね。

スライサーで選択する商品名を変えてもちゃんと動いています。

ALLSELECTED(‘2025_売上’)の部分はスライサーで使いたいデータが入っているテーブルを指定しています。つまり「2025_売上」テーブルのデータならスライサーやフィルターをかけることができるということです。

ここでは試していませんが、もし別テーブルのデータをスライサーで使いたいならそれも指定してあげないと動かないと思います。たぶん。

風場 輝

---

適当に作ったダミーデータでPower BI練習中。バージョンによっては画面がかなり変わることもあるのであしからず。
この記事作成時のPower BI Desktopバージョンは「2.139.2054.0 64-bit (2025年1月)」

ぴ

この表を使おう。まずはAND条件とOR条件ができるようにしようか

IF関数でAND条件：AかつBのときCを表示する

ということで カテゴリ列が「野菜」かつ数量列が「150以上」ならば商品名列の値を返す というDAX関数を作ろうと思います。

文章で書くと長ったらしいのでまずは条件を分解してそれらをくっつける形でDAX関数を作りたいと思います。

DAX関数に盛り込む必要がある内容
①カテゴリ列が「野菜」である　→CALCULATE関数で指定
②数量列が「150以上」である　→CALCULATE関数で指定
③上記①②を両方満たすならば商品名列の値を返す　→AND条件

AND条件はそれぞれの条件を「&&」でつなぎます。

IF_AND条件 = 
--カテゴリが野菜かつ数量が150以上ならば商品名を返す
VAR Category = CALCULATE(MAX('2025_売上'[カテゴリ]) = "野菜" )
VAR Quantity = CALCULATE(SUM('2025_売上'[数量]) >= 150 )

RETURN
IF(Category && Quantity , MAX('2025_売上'[商品名]))

ぴ

①から順に記載するとこんな感じだね。変数を使わなくてもできるよ

も

横棒2本を書いてから文字を書くとコメント扱いになるんだ！知らなかった

も

条件を満たさないときに×って返したいときは IF(Category && Quantity , MAX(‘2025_売上'[商品名]),”×”)ってすればいいよ

それでは、ちゃんとDAX関数が機能しているか確認してみましょう。

確認ポイント
・数量が150以上だろうとカテゴリが果物なら問答無用で除外されているか
・カテゴリが野菜でも数量が150未満のものは除外されているか
・条件に合う場合、商品名が表示されているか

ぷ

見た感じ大丈夫そう

IF関数でOR条件：AまたはBのときCを表示する

同じように カテゴリ列が「野菜」または数量列が「150以上」ならば商品名列の値を返す というDAX関数を作ろうと思います。

DAX関数に盛り込む必要がある内容
①カテゴリ列が「野菜」である　→CALCULATE関数で指定
②数量列が「150以上」である　→CALCULATE関数で指定
③上記①②をどちらか一方でも満たすならば商品名列の値を返す　→OR条件

OR条件はそれぞれの条件を「||」でつなぎます。
私のキーボードだと右上にあって円マークと同じキーです。Shiftキーを押しながらクリックすればいけます。

IF_OR条件 = 
--カテゴリが野菜または数量が150以上ならば商品名を返す
VAR Category = CALCULATE(MAX('2025_売上'[カテゴリ]) = "野菜" )
VAR Quantity = CALCULATE(SUM('2025_売上'[数量]) >= 150 )

RETURN
IF(Category || Quantity , MAX('2025_売上'[商品名]))

こちらも確認してみましょう。果物も範囲に入ったので増えているはずです。

確認ポイント
・数量が150未満だろうとカテゴリが野菜なら問答無用で表示されているか
・カテゴリが果物でも数量が150以上なら表示されているか
・条件に合う場合、商品名が表示されているか

も

大丈夫そう。キャベツ、さくらんぼ、ほうれん草が仲間入りしたね

・・・

まって今ふと気が付いたんですけどスイカって野菜では？

ぴ

軽く調べてみたけど、なんかどっちでも大丈夫っぽい

なるほど。果実的野菜。。。いろいろあるんだ。
まぁ野菜派の方はPower Queryから置換で変えてください。

閑話休題。

完成
AND条件とOR条件のDAX関数を入れました。

もう少しシンプルな条件指定の記事ならこちら↓